{ pkgs }:
let
  pname = "OpenGOAL-Launcher";
  version = "2.10.4";

  src = pkgs.fetchurl {
    url = "https://github.com/open-goal/launcher/releases/download/v${version}/${pname}_${version}_amd64.AppImage";
    hash = "sha256-eikzjdOYNdJM9FM3O/HuCFDzf97Fm1nhbRedDyKZ1/s=";
  };
in
pkgs.stdenvNoCC.mkDerivation {
  inherit pname version src;

  nativeBuildInputs = [ pkgs.makeWrapper ];

  dontUnpack = true;
  dontPatchELF = true;

  installPhase = ''
    runHook preInstall

    cp "$src" "${pname}.AppImage"
    chmod +x "${pname}.AppImage"
    ./"${pname}.AppImage" --appimage-extract

    mkdir -p "$out/opt"
    cp -a AppDir "$out/opt/opengoal-launcher"
    rm -f "$out/opt/opengoal-launcher/share/icons/hicolor/scalable/apps/byobu.svg"

    makeWrapper "$out/opt/opengoal-launcher/AppRun" "$out/bin/${pname}"
    install -Dm444 "AppDir/${pname}.desktop" \
      "$out/share/applications/${pname}.desktop"
    install -Dm444 "AppDir/${pname}.png" \
      "$out/share/icons/hicolor/256x256/apps/${pname}.png"

    runHook postInstall
  '';

  passthru.updateScript = pkgs.nix-update-script { };

  meta = with pkgs.lib; {
    description = "Launcher for the OpenGOAL project";
    homepage = "https://github.com/open-goal/launcher";
    license = licenses.mit;
    platforms = [ "x86_64-linux" ];
    sourceProvenance = with sourceTypes; [ binaryNativeCode ];
    mainProgram = pname;
  };
}