add: apple container build target

2026-09-02 13:21:30 -04:00
parent 52e8bf19e0
commit 9b1238eb39
4 changed files with 60 additions and 42 deletions
@@ -0,0 +1,43 @@
+final: prev:
+let
+  rustLatest = prev.rust-bin.stable.latest.default;
+  rustPlatform = prev.makeRustPlatform {
+    cargo = rustLatest;
+    rustc = rustLatest;
+  };
+in
+{
+  atuinLatest = (prev.atuin.override { inherit rustPlatform; }).overrideAttrs (oldAttrs: rec {
+    version = "18.19.0";
+
+    src = prev.fetchFromGitHub {
+      owner = "atuinsh";
+      repo = "atuin";
+      rev = "v${version}";
+      hash = "sha256-yAw+ty6FUnFbiRTdAe2QQHzj6uU24fZ/bEIXcHl/thg=";
+    };
+
+    cargoDeps = rustPlatform.fetchCargoVendor {
+      inherit src;
+      hash = "sha256-jirVe0+N5+UHZWioj8AipUhawMBameqEJJpa8HPTnfw=";
+    };
+
+    cargoBuildFeatures = [
+      "ai"
+      "client"
+      "clipboard"
+      "daemon"
+      "hex"
+      "sync"
+    ];
+    cargoCheckFeatures = cargoBuildFeatures;
+
+    preCheck = (oldAttrs.preCheck or "") + ''
+      export HOME="$TMPDIR"
+      export XDG_CONFIG_HOME="$TMPDIR/.config"
+      export XDG_DATA_HOME="$TMPDIR/.local/share"
+      export XDG_STATE_HOME="$TMPDIR/.local/state"
+      mkdir -p "$XDG_CONFIG_HOME" "$XDG_DATA_HOME" "$XDG_STATE_HOME"
+    '';
+  });
+}