nix-config-v2/flake.nix

{
  description = "Wyatt's nix configuration suite";
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-25.05";
    nix-flatpak.url = "github:gmodena/nix-flatpak/?ref=v0.6.0";
    home-manager = {
      url = "github:nix-community/home-manager/release-25.05";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    darwin = {
      url = "github:lnl7/nix-darwin/nix-darwin-25.05";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    ghostty.url = "github:ghostty-org/ghostty";
    quadlet-nix.url = "github:SEIAROTg/quadlet-nix";
  };

  outputs = inputs @ {
    self,
    nixpkgs,
    nix-flatpak,
    darwin,
    home-manager,
    ghostty,
    quadlet-nix,
    ...
  }: let
    userName = "wyatt";
    userEmail = "wyatt@wyattjmiller.com";
    extraSpecialArgs = {
      inherit userName userEmail ghostty;
    };
  in {
    meta = import ./meta;

    # Primary laptop - MacBook Pro (2023, M3)
    darwinConfigurations."sephiroth" = darwin.lib.darwinSystem {
      system = "aarch64-darwin";
      specialArgs = {
        inherit userName userEmail ghostty;
        hostname = "sephiroth";
        role = "devel";
      };
      modules = [
        ./modules/common
        ./modules/machine/sephiroth

        home-manager.darwinModules.home-manager
        {
          home-manager.useGlobalPkgs = true;
          home-manager.useUserPackages = true;
          home-manager.extraSpecialArgs = extraSpecialArgs;
          home-manager.users.${userName} = import ./home;
        }
      ];
    };

    # Primary desktop computer
    nixosConfigurations."cloud" = nixpkgs.lib.nixosSystem {
      system = "x86_64-linux";
      specialArgs = {
        inherit userName userEmail ghostty;
        hostname = "cloud";
        role = "devel";
      };
      modules = [
        nix-flatpak.nixosModules.nix-flatpak
        ./modules/common
        ./modules/machine/cloud

        home-manager.nixosModules.home-manager
        {
          home-manager.useGlobalPkgs = true;
          home-manager.useUserPackages = true;
          home-manager.extraSpecialArgs = extraSpecialArgs;
          home-manager.users.${userName}.imports = [
            ./home
          ];
        }
      ];
    };

    # Apartment appliance server
    nixosConfigurations."valefor" = nixpkgs.lib.nixosSystem {
      system = "x86_64-linux";
      specialArgs = {
        inherit userName userEmail;
        hostname = "valefor";
        role = "server";
      };
      modules = [
        ./modules/common
        ./modules/machine/valefor

        home-manager.nixosModules.home-manager
        {
          home-manager.useGlobalPkgs = true;
          home-manager.useUserPackages = true;
          home-manager.extraSpecialArgs = extraSpecialArgs;
          home-manager.users.${userName}.imports = [
            ./home
          ];
        }
      ];
    };

    # Storage, status, game, and media server
    nixosConfigurations."ixion" = nixpkgs.lib.nixosSystem {
      system = "x86_64-linux";
      specialArgs = {
        inherit userName userEmail;
        hostname = "ixion";
        role = "server";
      };
      modules = [
        nix-flatpak.nixosModules.nix-flatpak
        ./modules/common
        ./modules/machine/ixion

        home-manager.nixosModules.home-manager
        {
          home-manager.useGlobalPkgs = true;
          home-manager.useUserPackages = true;
          home-manager.extraSpecialArgs = extraSpecialArgs;
          home-manager.users.${userName}.imports = [
            ./home
          ];
        }
      ];
    };
  };
}