nix-config-v2/modules/common/overlays.nix

final: prev: let
  rust_1_90_0 = prev.rust-bin.stable."1.90.0".default;
  myRustPlatform = prev.makeRustPlatform {
    cargo = rust_1_90_0;
    rustc = rust_1_90_0;
  };
in {
  lazygitLatest = prev.lazygit.overrideAttrs (_: rec {
    version = "0.55.1";
    src = prev.fetchFromGitHub {
      owner = "jesseduffield";
      repo = "lazygit";
      rev = "v${version}";
      hash = "sha256-UofhgILZhVXnYiGpb25m4Ct4sbu5pRmjVgj3oEf5Uyk=";
    };
    vendorHash = null;
    subPackages = [ "." ];
    ldflags = [
      "-X main.version=${version}"
      "-X main.buildSource=nix"
    ];
  });

  atuinLatest = (prev.atuin.override {
    rustPlatform = myRustPlatform;
  }).overrideAttrs (oldAttrs: rec {
    version = "18.10.0";

    src = prev.fetchFromGitHub {
      owner = "atuinsh";
      repo = "atuin";
      rev = "v${version}";
      hash = "sha256-bfSa3RtVXxHt3usDqqpE/oXKKDUZOrf+tD9uL59fr6M=";
    };

    cargoDeps = myRustPlatform.fetchCargoVendor {
      # name = "atuin-${version}-vendor.tar.gz";
      inherit src;
      hash = "sha256-67ffivZVCly1GWA3fJ9mT8nGv2EGd6eCthbaIu/IW3M=";
    };

    preCheck = (oldAttrs.preCheck or "") + ''
      export HOME="$TMPDIR"
      export XDG_CONFIG_HOME="$TMPDIR/.config"
      export XDG_DATA_HOME="$TMPDIR/.local/share"
      export XDG_STATE_HOME="$TMPDIR/.local/state"
      mkdir -p "$XDG_CONFIG_HOME" "$XDG_DATA_HOME" "$XDG_STATE_HOME"
    '';
  });

  k9sLatest = prev.k9s.overrideAttrs (oldAttrs: rec {
    version = "0.30.16";
    src = prev.fetchFromGitHub {
      owner = "derailed";
      repo = "k9s";
      rev = "v${version}";
      hash = "sha256-1z6r6v3n1p6vd2q6n4pl5q3f7q3q7q1p7j5j1k3l4m5n6o7p8q9r";
    };
    ldflags = [
      "-X github.com/derailed/k9s/version.Version=${version}"
      "-X github.com/derailed/k9s/version.BuildSource=nix"
    ];
  });
}