nix-config-v2/modules/common/overlays.nix

final: prev: let
  rust_latest = prev.rust-bin.stable.latest.default;
  golang_latest = prev.go-bin.latestStable;
  buildGoModuleLatest = prev.buildGoModule.override {
    go = golang_latest;
  };
  myRustPlatform = prev.makeRustPlatform {
    cargo = rust_latest;
    rustc = rust_latest;
  };
in {
  lazygitLatest = prev.lazygit.overrideAttrs (_: rec {
    version = "0.61.0";
    src = prev.fetchFromGitHub {
      owner = "jesseduffield";
      repo = "lazygit";
      rev = "v${version}";
      hash = "sha256-G7JulCK9WUVWbp1V7lYuM3fehCdn1cNAJHYjr3aKDvQ=";
    };

    vendorHash = null;
    subPackages = [ "." ];
    ldflags = [
      "-X main.version=${version}"
      "-X main.buildSource=nix"
    ];
  });

  atuinLatest = (prev.atuin.override {
    rustPlatform = myRustPlatform;
  }).overrideAttrs (oldAttrs: rec {
    version = "18.13.6";

    src = prev.fetchFromGitHub {
      owner = "atuinsh";
      repo = "atuin";
      rev = "v${version}";
      hash = "sha256-yAw+ty6FUnFbiRTdAe2QQHzj6uU24fZ/bEIXcHl/thg=";
    };

    cargoDeps = myRustPlatform.fetchCargoVendor {
      # name = "atuin-${version}-vendor.tar.gz";
      inherit src;
      hash = "sha256-jirVe0+N5+UHZWioj8AipUhawMBameqEJJpa8HPTnfw=";
    };

    cargoBuildFeatures = [
      "ai"
      "client"
      "clipboard"
      "daemon"
      "hex"
      "sync"
    ];
    cargoCheckFeatures = cargoBuildFeatures;

    preCheck = (oldAttrs.preCheck or "") + ''
      export HOME="$TMPDIR"
      export XDG_CONFIG_HOME="$TMPDIR/.config"
      export XDG_DATA_HOME="$TMPDIR/.local/share"
      export XDG_STATE_HOME="$TMPDIR/.local/state"
      mkdir -p "$XDG_CONFIG_HOME" "$XDG_DATA_HOME" "$XDG_STATE_HOME"
    '';
  });

  # k9sLatest = prev.k9s.overrideAttrs (oldAttrs: rec {
  #   version = "0.30.16";
  #   src = prev.fetchFromGitHub {
  #     owner = "derailed";
  #     repo = "k9s";
  #     rev = "v${version}";
  #     hash = "sha256-1z6r6v3n1p6vd2q6n4pl5q3f7q3q7q1p7j5j1k3l4m5n6o7p8q9r";
  #   };
  #   ldflags = [
  #     "-X github.com/derailed/k9s/version.Version=${version}"
  #     "-X github.com/derailed/k9s/version.BuildSource=nix"
  #   ];
  # });

  ghDashLatest = (prev.gh-dash.override {
    buildGoModule = buildGoModuleLatest;
  }).overrideAttrs (oldAttrs: rec {
    version = "4.23.2";
    src = prev.fetchFromGitHub {
      owner = "dlvhdr";
      repo = "gh-dash";
      rev = "v${version}";
      hash = "sha256-C06LPVoE23ITJpMG0x75Djgeup+eb5uYwA8wL7xxvWU=";
    };

    vendorHash = "sha256-4AbeoH0l7eIS7d0yyJxM7+woC7Q/FCh0BOJj3d1zyX4=";
    doCheck = false;
    checkFlags = [
      "-skip=TestFullOutput"
    ];

    ldflags = [
      "-s"
      "-w"
      "-X github.com/dlvhdr/gh-dash/v4/cmd.Version=${version}"
    ];

    passthru = (oldAttrs.passthru or {}) // {
      tests = {
        version = oldAttrs.testers.testVersion { package = final.ghDashLatest; };
      };
    };
  });

  diffNavLatest = (prev.diffnav.override {
    buildGoModule = buildGoModuleLatest;
  }).overrideAttrs (_: rec {
    version = "0.10.0";
    src = prev.fetchFromGitHub {
      owner = "dlvhdr";
      repo = "diffnav";
      rev = "v${version}";
      hash = "sha256-6VtAQzZNLQrf8QYVXxLUgb3F6xguFDbwaE9kahPhbSE=";
    };

    vendorHash = "sha256-gmmckzR0D1oFuTG5TAb6gLMoNbcZl9EsjbFjhPfJqnQ=";

    ldflags = [
      "-s"
      "-w"
    ];
  });
}